home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 010 / antdesgn.arc / MSANT.BAS < prev    next >
Encoding:
BASIC Source File  |  1980-01-01  |  3.4 KB  |  126 lines
  1. 10 REM ANALYSIS PROGRAM FOR MICROSTRIP ANTENNAS
  2. 20 REM "ANTENNA DESIGN USING PERSONAL COMPUTERS"
  3. 30 REM K. CARVER'S CAVITY MODEL
  4. 40 DIM FLDA(180)
  5. 50 PI=3.141593
  6. 60 DEF FNLOG10(X)=.4343*LOG(X)
  7. 70 KEY OFF
  8. 80 SCREEN 0,1
  9. 90 CLS
  10. 100 COLOR 1,0
  11. 110 PRINT "MICROSTRIP ANTENNA ANALYSIS"
  12. 120 COLOR 4,0
  13. 130 PRINT
  14. 140 INPUT "TYPE PATCH RESONANT LENGTH(cm)";L1
  15. 150 INPUT "TYPE PATCH WIDTH(cm)";W1
  16. 160 INPUT "TYPE DIELECTRIC CONSTANT";DC
  17. 170 INPUT "TYPE SUBSTRATE THICKNESS(cm)";THK
  18. 180 INPUT "TYPE LOSS TANGENT";LT
  19. 190 IF LT<1E-08 THEN LT=1E-08
  20. 200 INPUT "TYPE DISTANCE FROM FEED PT. TO RAD. EDGE(cm)";DIST
  21. 210 COLOR 14,0
  22. 220 F1=SQR(1/(1+10*THK/W1))
  23. 230 REM EFFECTIVE DIELECTRIC CONSTANT
  24. 240 EDC=(DC+1)/2+(DC-1)/2*F1
  25. 250 REM AW=2*L1*SQR(EDC)
  26. 260 AW=2.08*L1*SQR(DC)
  27. 270 REM WALL CONDUCTANCE
  28. 280 GWL=8.360001E-03*W1/AW
  29. 290 REM EFFECTIVE LENGTH EXTENSION
  30. 300 K=.412*((EDC+.3)/(EDC-.258))*((W1/THK+.262)/(W1/THK+.813))
  31. 310 REM WALL SUSCEPTANCE
  32. 320 BWL=.01668*K*(L1/AW)*EDC
  33. 330 F=.7747+.5977*(W1/L1-1)-.1638*(W1/L1-1)^2
  34. 340 ALR=-2362*THK*BWL*F/(AW*W1)
  35. 350 ALI=2362*THK*GWL*F/(AW*W1)
  36. 360 KPR=ALR*L1
  37. 370 KPI=ALI*L1
  38. 380 DEL0=0
  39. 390 DELI=0
  40. 400 FOR N=1 TO 4
  41. 410 P=2*KPR*(PI-DEL0)+2*KPI*DEL1
  42. 420 Q=KPR*KPR-KPI*KPI+DEL1*DEL1-PI*PI+DEL0*(2*PI-DEL0)
  43. 430 R=2*KPI*(PI-DEL0)-2*KPR*DEL1
  44. 440 S=2*DEL1*(PI-DEL0)+2*KPI*KPR
  45. 450 W=(DEL0^3-DEL1^2*DEL0-2*DEL0*DEL1^2)/3
  46. 460 X=(-DEL1^3+DEL0^2*DEL1+2*DEL0^2*DEL1)/3
  47. 470 DEL0=(P*Q+R*S)/(Q*Q+S*S)-W
  48. 480 DEL1=(R*Q-S*P)/(Q*Q+S*S)-X
  49. 490 NEXT N
  50. 500 EGR=PI/L1-DEL0/L1
  51. 510 EGI=-DEL1/L1
  52. 520 FR=.5*PI*3*EGR/SQR(DC)
  53. 530 PRINT
  54. 540 PRINT USING "THE RESONANT FREQUENCY IS ###.###GHz";FR
  55. 550 Q0=EGR/(2*EGI)
  56. 560 CAP=(DC*8.85E-12*W1*L1/10000)/(2*THK/100)
  57. 570 RES=Q0/(2*PI*FR*1E+09*CAP)
  58. 580 PRINT USING "THE RADIATION RESISTANCE IS ####.## ohms";RES
  59. 590 RIN=RES*COS(PI*DIST/L1)^2
  60. 600 PRINT USING "INPUT RESISTANCE AT FEED IS ###.## ohms";RIN
  61. 610 SD=1/SQR(PI*FR*1E+09*4*PI*5.7)
  62. 620 QC=THK/100/SD
  63. 630 QD=1/LT
  64. 640 X0=1/Q0+1/QC+1/QD
  65. 650 QT=1/X0
  66. 660 VSWR=2
  67. 670 BW=(VSWR-1)/(QT*SQR(VSWR))
  68. 680 BW=100*BW
  69. 690 PRINT USING "THE BANDWIDTH IS ##.#%";BW
  70. 700 PRINT
  71. 710 COLOR 4,0
  72. 720 INPUT "DO YOU WANT TO PLOT PATTERNS(Y,N)";IP$
  73. 730 IF IP$="N" THEN GOTO 1200
  74. 740 INPUT "E-PLANE(E) OR H-PLANE(H) PATTERN";IP$
  75. 750 IF IP$="E" OR IP$="H" THEN GOTO 770
  76. 760 GOTO 740
  77. 770 FMAX=0
  78. 780 XK0=2*PI*FR/.3
  79. 790 AE=XK0*L1/200
  80. 800 AH=XK0*W1/200
  81. 810 FOR TH=0 TO 90
  82. 820 IND=TH+90
  83. 830 THR=TH*PI/180
  84. 840 STH=SIN(THR)
  85. 850 FLDA(IND)=1
  86. 860 IF STH=0 THEN GOTO 890
  87. 870 IF IP$="E" THEN FLDA(IND)=ABS(COS(AE*STH))
  88. 880 IF IP$="H" THEN FLDA(IND)=ABS(SIN(AH*STH)*COS(THR)/(AH*STH))
  89. 890 IF FLDA(IND)>FMAX THEN FMAX=FLDA(IND)
  90. 900 FLDA(180-IND)=FLDA(IND)
  91. 910 NEXT TH
  92. 920 PRINT
  93. 930 REM NORMALIZE DATA
  94. 940 FOR TH=0 TO 180
  95. 950 FM=FLDA(TH)/FMAX
  96. 960 IF FM<.0316 THEN FM=.0316
  97. 970 FLDA(TH)=20*FNLOG10(FM)
  98. 980 NEXT TH
  99. 990 REM PLOT GRID
  100. 1000 SCREEN 0,1
  101. 1010 CLS
  102. 1020 SCREEN 2,0
  103. 1030 VIEW (262,20)-(638,188)
  104. 1040 WINDOW (-1,-1)-(1,1)
  105. 1050 CIRCLE (0,0),1,,,,.45
  106. 1060 CIRCLE (0,0),.666,,,,.45
  107. 1070 CIRCLE (0,0),.333,,,,.45
  108. 1080 FOR THD=0 TO 150 STEP 30
  109. 1090 TH=THD*PI/180
  110. 1100 LINE (COS(TH),SIN(TH))-(-COS(TH),-SIN(TH))
  111. 1110 NEXT THD
  112. 1120 PSET (FLDA(0),0)
  113. 1130 FOR TH=0 TO 180
  114. 1140 THR=TH*PI/180
  115. 1150 RAD=FLDA(TH)/30+1
  116. 1160 LINE -(RAD*COS(THR),RAD*SIN(THR))
  117. 1170 NEXT TH
  118. 1180 PRINT USING "&-PLANE PATTERN";IP$
  119. 1190 GOTO 720
  120. 1200 INPUT "CONTINUE(Y,N)";ST$
  121. 1210 IF ST$<>"N" THEN GOTO 80
  122. 1220 SCREEN 0,1
  123. 1230 COLOR 7,0
  124. 1240 KEY ON
  125. 1250 END
  126.